home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 010 / antdesgn.arc / LINE.BAS < prev    next >
Encoding:
BASIC Source File  |  1980-01-01  |  3.1 KB  |  115 lines
  1. 10 REM LINE SOURCE ANTENNA PATTERNS
  2. 20 REM "ANTENNA DESIGN USING PERSONAL COMPUTERS"
  3. 30 DIM FLDA(360)
  4. 40 PI=3.141593
  5. 50 KEY OFF
  6. 60 DEF FNLOG10(X)=.4343*LOG(X)
  7. 70 SCREEN 0,1
  8. 80 CLS
  9. 90 COLOR 1,0
  10. 100 PRINT "RADIATION INTEGRAL AND PATTERNS FOR A TRAVELING WAVE LINE SOURCE"
  11. 110 COLOR 4,0
  12. 120 PRINT
  13. 130 INPUT "WHAT IS THE LINE SOURCE LENGTH(WAVELENGTHS)";L
  14. 140 INPUT "WHAT IS THE NORMALIZED PHASE CONSTANT";B0
  15. 150 INPUT "DO YOU WANT TO INCLUDE A SIN(THETA) ELEMENT FACTOR(Y,N)";EP$
  16. 160 PRINT "SELECT THE DESIRED CURRENT DISTRIBUTION AMPLITUDE:"
  17. 170 PRINT "           1-UNIFORM"
  18. 180 PRINT "           2-TRIANGULAR"
  19. 190 PRINT "           3-COSINE"
  20. 200 PRINT "           4-COSINE SQUARED"
  21. 210 PRINT "           5-COSINE ON A PEDESTAL"
  22. 220 PRINT "           6-EXIT"
  23. 230 INPUT ID
  24. 240 IF ID<1 OR ID>6 THEN GOTO 160
  25. 250 IF ID=6 THEN GOTO 1110
  26. 260 C=.5
  27. 270 IF ID=5 THEN INPUT "WHAT IS THE RELATIVE HEIGHT OF THE PEDESTAL(0 TO 1)";C
  28. 280 IF C<0 OR C>1 THEN GOTO 270
  29. 290 ROD=PI/180
  30. 300 COLOR 14,0
  31. 310 REM COMPUTE PATTERN
  32. 320 FOR I=0 TO 180
  33. 330 TH=I*ROD
  34. 340 FLDA(I)=1
  35. 350 CTH=COS(TH)
  36. 360 U=PI*L*(CTH+B0)
  37. 370 IF ID>1 THEN GOTO 410
  38. 380 REM UNIFORM
  39. 390 IF ABS(U)>.01 THEN FLDA(I)=SIN(U)/U
  40. 400 GOTO 660
  41. 410 IF ID>2 THEN GOTO 450
  42. 420 REM TRIANGULAR
  43. 430 IF ABS(U)>.01 THEN FLDA(I)=(SIN(U/2)/(U/2))^2
  44. 440 GOTO 660
  45. 450 IF ID>3 THEN GOTO 510
  46. 460 REM COSINE
  47. 470 FLDA(I)=.7854
  48. 480 DEN=1-(2*U/PI)^2
  49. 490 IF ABS(DEN)>.01 THEN FLDA(I)=COS(U)/DEN
  50. 500 GOTO 660
  51. 510 IF ID>4 THEN GOTO 580
  52. 520 REM COSINE SQUARED
  53. 530 IF ABS(U)<.01 THEN GOTO 660
  54. 540 FLDA(I)=.5
  55. 550 DEN=U*(1-U*U/(PI^2))
  56. 560 IF ABS(DEN)>.01 THEN FLDA(I)=SIN(U)/DEN
  57. 570 GOTO 660
  58. 580 IF ID>5 THEN GOTO 1110
  59. 590 REM COSINE ON A PEDESTAL
  60. 600 T1=1
  61. 610 IF ABS(U)>.01 THEN T1=SIN(U)/U
  62. 620 T2=.7854
  63. 630 DEN=1-(2*U/PI)^2
  64. 640 IF ABS(DEN)>.01 THEN T2=COS(U)/DEN
  65. 650 FLDA(I)=(C*T1+(1-C)*T2*2/PI)/(C+(1-C)*2/PI)
  66. 660 FLDA(I)=ABS(FLDA(I))
  67. 670 IF EP$<>"N" THEN FLDA(I)=FLDA(I)*SIN(TH)
  68. 680 NEXT I
  69. 690 PRINT
  70. 700 REM COMPUTE BEAM POINTING ANGLE
  71. 710 FM=0
  72. 720 FOR I=0 TO 180
  73. 730 IF FLDA(I)=>FM THEN IMAX=I
  74. 740 IF FLDA(I)>FM THEN FM=FLDA(I)
  75. 750 NEXT I
  76. 760 FOR I=0 TO 180
  77. 770 FLDA(I)=FLDA(I)/FM
  78. 780 IF FLDA(I)<.0316 THEN FLDA(I)=.0316
  79. 790 FLDA(I)=20*FNLOG10(FLDA(I))
  80. 800 FLDA(360-I)=FLDA(I)
  81. 810 NEXT I
  82. 820 REM COMPUTE BEAMWIDTH
  83. 830 I=IMAX-1
  84. 840 I=I+1
  85. 850 IF FLDA(I)>-3 THEN GOTO 840
  86. 860 TH0=(-3-FLDA(I-1)+(I-1)*(FLDA(I)-FLDA(I-1)))/(FLDA(I)-FLDA(I-1))
  87. 870 BW=(TH0-IMAX)*2
  88. 880 SCREEN 2,0
  89. 890 VIEW (262,20)-(638,188)
  90. 900 WINDOW (-1,-1)-(1,1)
  91. 910 PRINT USING "BEAM MAX. AT ### degrees";IMAX
  92. 920 PRINT USING "BEAMWIDTH=###.# degrees";BW
  93. 930 REM PLOT GRID
  94. 940 CIRCLE (0,0),1,,,,.45
  95. 950 CIRCLE (0,0),.666,,,,.45
  96. 960 CIRCLE (0,0),.333,,,,.45
  97. 970 FOR THD=0 TO 150 STEP 30
  98. 980 TH=THD*ROD
  99. 990 LINE (COS(TH),SIN(TH))-(-COS(TH),-SIN(TH))
  100. 1000 NEXT THD
  101. 1010 PSET (0,FLDA(0)/30+1)
  102. 1020 FOR TH=0 TO 360
  103. 1030 THR=TH*ROD
  104. 1040 RAD=FLDA(TH)/30+1
  105. 1050 LINE -(RAD*SIN(THR),RAD*COS(THR))
  106. 1060 NEXT TH
  107. 1070 PRINT "10dB/DIV."
  108. 1080 PRINT
  109. 1090 INPUT "CONTINUE(Y,N)";K$
  110. 1100 IF K$<>"N" THEN GOTO 70
  111. 1110 SCREEN 0,1
  112. 1120 COLOR 7,0
  113. 1130 KEY ON
  114. 1140 END
  115.